android-methods-profiler/app/build.gradle.kts at 4321cbda0f3de03279fbccce4783b1130f90276c · Grigory-Rylov/android-methods-profiler · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
import org.gradle.internal.os.OperatingSystem
import org.gradle.api.tasks.bundling.Jar
import org.gradle.process.ExecOperations

plugins {
    java
    kotlin("jvm")
}

val properties: (String) -> String = { key ->
    project.findProperty(key).toString()
}

group = properties("pluginGroup")
version = properties("yampVersion")

configure<JavaPluginConvention> {
    sourceCompatibility = JavaVersion.VERSION_17
}

sourceSets {
    main {
        java {
            if (OperatingSystem.current().isMacOsX) {
                srcDir("src/mac/java")
            } else {
                srcDir("src/default/java")
            }
        }
    }
}

repositories {
    mavenCentral()
}

dependencies {
    implementation(project(":core"))
    implementation("com.github.Grigory-Rylov:adb-facade-core:0.1.8")
    implementation("com.github.Grigory-Rylov:adb-facade-ddmlib:0.1.2")
    implementation("com.github.Grigory-Rylov:andoid_method_trace_recorder:2.1.0")
    implementation("com.github.Grishberg:tree-table:0.1.1")
    implementation("org.jetbrains.kotlinx:kotlinx-coroutines-core:1.3.2")
    implementation("com.android.tools.ddms:ddmlib:26.6.3")
    implementation("com.google.code.gson:gson:2.8.6")
    implementation("org.slf4j:slf4j-api:1.7.25")
    implementation("org.slf4j:slf4j-log4j12:1.7.25")
    implementation("log4j:log4j:1.2.17")

    testImplementation("junit:junit:4.12")
    testImplementation("org.mockito:mockito-core:2.23.0")
    testImplementation("com.nhaarman.mockitokotlin2:mockito-kotlin:2.1.0")
    testImplementation("org.jetbrains.kotlinx:kotlinx-coroutines-test:1.3.2")
}

tasks.withType<JavaCompile> {
    options.compilerArgs.add("-XDignore.symbol.file=true")
}

tasks.register<Jar>("fatJar") {
    manifest {
        attributes(
            "Main-Class" to "com.github.grishberg.profiler.Launcher",
            "Implementation-Title" to "Android Methods Profiler",
            "Implementation-Version" to archiveVersion
        )
    }

    duplicatesStrategy = DuplicatesStrategy.EXCLUDE

    archiveBaseName.set("yamp")

    from(configurations.runtimeClasspath.get().map {
        if (it.isDirectory) it else zipTree(it)
    }) {
        exclude("MaterialUISwingDemo*.class")
        exclude("module-info.class")
    }

    with(tasks.jar.get())
}

val installerScript = when {
    OperatingSystem.current().isLinux -> "build_scripts/linuxApplication"
    OperatingSystem.current().isWindows -> ""
    OperatingSystem.current().isMacOsX -> "build_scripts/macosx.sh"
    else -> ""
}

tasks.register<Exec>("buildInstaller") {
    dependsOn("fatJar")
    workingDir(file("."))
    println("Current WD: ${workingDir}")
    commandLine("./$installerScript", version.toString())
}