Upgrade to libuv v1.26.0.

That required to change how WriteUnixTransport monitors the pipe for an
EOF event.  Prior to libuv v1.23.1 it was possible to use uv_read_start
for that purpose.  Now we're using a throw away uv_poll_t to monitor for
UV_DISCONNECT.

Author: 1st1

uvloop/handles/pipe.pxd

@@ -27,6 +27,10 @@ cdef class ReadUnixTransport(UVStream):
 
 cdef class WriteUnixTransport(UVStream):
 
+    cdef:
+        uv.uv_poll_t disconnect_listener
+        bint disconnect_listener_inited
+
     @staticmethod
     cdef WriteUnixTransport new(Loop loop, object protocol, Server server,
                                 object waiter)

uvloop/handles/pipe.pyx

@@ -147,6 +147,10 @@ cdef class ReadUnixTransport(UVStream):
 @cython.no_gc_clear
 cdef class WriteUnixTransport(UVStream):
 
+    def __cinit__(self):
+        self.disconnect_listener_inited = False
+        self.disconnect_listener.data = NULL
+
     @staticmethod
     cdef WriteUnixTransport new(Loop loop, object protocol, Server server,
                                   object waiter):
@@ -163,6 +167,46 @@ cdef class WriteUnixTransport(UVStream):
         __pipe_init_uv_handle(<UVStream>handle, loop)
         return handle
 
+    cdef _start_reading(self):
+        # A custom implementation for monitoring for EOF:
+        # libuv since v1.23.1 prohibits using uv_read_start on
+        # write-only FDs, so we use a throw-away uv_poll_t handle
+        # for that purpose, as suggested in
+        # https://github.com/libuv/libuv/issues/2058.
+
+        cdef int err
+
+        if not self.disconnect_listener_inited:
+            err = uv.uv_poll_init(self._loop.uvloop,
+                                  &self.disconnect_listener,
+                                  self._fileno())
+            if err < 0:
+                raise convert_error(err)
+            self.disconnect_listener.data = <void*>self
+            self.disconnect_listener_inited = True
+
+        err = uv.uv_poll_start(&self.disconnect_listener,
+                               uv.UV_READABLE | uv.UV_DISCONNECT,
+                               __on_write_pipe_poll_event)
+        if err < 0:
+            raise convert_error(err)
+
+    cdef _stop_reading(self):
+        cdef int err
+        if not self.disconnect_listener_inited:
+            return
+        err = uv.uv_poll_stop(&self.disconnect_listener)
+        if err < 0:
+            raise convert_error(err)
+
+    cdef _close(self):
+        if self.disconnect_listener_inited:
+            self.disconnect_listener.data = NULL
+            uv.uv_close(<uv.uv_handle_t *>(&self.disconnect_listener), NULL)
+            self.disconnect_listener_inited = False
+
+        UVStream._close(self)
+
     cdef _new_socket(self):
         return __pipe_get_socket(<UVSocketHandle>self)
 
@@ -176,6 +220,25 @@ cdef class WriteUnixTransport(UVStream):
         raise NotImplementedError
 
 
+cdef void __on_write_pipe_poll_event(uv.uv_poll_t* handle,
+                                     int status, int events) with gil:
+    cdef WriteUnixTransport tr
+
+    if handle.data is NULL:
+        return
+
+    tr = <WriteUnixTransport>handle.data
+    if tr._closed:
+        return
+
+    if events & uv.UV_DISCONNECT:
+        try:
+            tr._stop_reading()
+            tr._on_eof()
+        except BaseException as ex:
+            tr._fatal_error(ex, False)
+
+
 cdef class _PipeConnectRequest(UVRequest):
     cdef:
         UnixTransport transport

uvloop/includes/compat.h

@@ -3,11 +3,6 @@
 #include "uv.h"
 
 
-// uv_poll_event.UV_DISCONNECT is available since libuv v1.9.0
-#if UV_VERSION_HEX < 0x10900
-#define UV_DISCONNECT 0
-#endif
-
 #ifndef EWOULDBLOCK
 #define EWOULDBLOCK EAGAIN
 #endif

uvloop/includes/uv.pxd

@@ -4,12 +4,6 @@ from posix.types cimport gid_t, uid_t
 from . cimport system
 
 
-cdef extern from "includes/compat.h":
-    # Member of uv_poll_event, in compat.h for compatibility
-    # with libuv < v1.9.0
-    cdef int UV_DISCONNECT
-
-
 cdef extern from "uv.h" nogil:
     cdef int UV_TCP_IPV6ONLY
 
@@ -190,7 +184,7 @@ cdef extern from "uv.h" nogil:
     ctypedef enum uv_poll_event:
         UV_READABLE = 1,
         UV_WRITABLE = 2
-        # UV_DISCONNECT = 4 ; see compat.h for details
+        UV_DISCONNECT = 4
 
     ctypedef enum uv_membership:
         UV_LEAVE_GROUP = 0,