render-markdown.nvim/justfile at main · MeanderingProgrammer/render-markdown.nvim · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
init := "tests/minimal_init.lua"
settings := "{ minimal_init = " + quote(init) + ", sequential = true, keep_going = false }"

default: update check test bench health

update:
  # keep documentation in sync with code
  python scripts/update.py
  # https://github.com/kdheepak/panvimdoc
  ../../tools/panvimdoc/panvimdoc.sh \
    --project-name render-markdown \
    --input-file README.md

check:
  selene --quiet .
  stylua --check .

test:
  just busted "tests"

bench:
  python scripts/generate.py
  just busted "benches"

[private]
busted path:
  nvim --headless --noplugin -u {{init}} -c "PlenaryBustedDirectory {{path}} {{settings}}"

health:
  nvim -c "checkhealth render-markdown" -- -

log:
  cat ~/.local/state/nvim/render-markdown.log

demo: heading table quote callout latex

heading:
  python demo/run.py --name "heading_code"

table:
  python demo/run.py --name "list_table"

quote:
  python demo/run.py --name "box_dash_quote"

callout:
  python demo/run.py --name "callout"

latex:
  python demo/run.py --name "latex"