vkdt/flake.nix at master · hanatos/vkdt · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
{
  description = "raw photography workflow that sucks less";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    utils.url = "github:numtide/flake-utils";
  };

  outputs =
    {
      self,
      nixpkgs,
      utils,
      ...
    }:
    utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs { inherit system; };
      in
      {
        packages = rec {
          vkdt-git = pkgs.stdenv.mkDerivation rec {
            pname = "vkdt";
            version = "git";

            src = pkgs.lib.cleanSource ./.;

            cargoRoot = "src/pipe/modules/i-raw/rawloader-c";

            cargoDeps = pkgs.rustPlatform.fetchCargoVendor {
              inherit pname src cargoRoot;
              hash = "sha256-ozPrxEVMihw1usPlI/+vp+fJIjI8P+hN8gcD+Tsdwgw=";
            };

            strictDeps = true;

            nativeBuildInputs = with pkgs; [
              cargo
              clang
              git
              glslang
              llvm
              llvmPackages.openmp
              pkg-config
              rsync
              rustPlatform.cargoSetupHook
              xxd
            ];

            buildInputs = with pkgs; [
              exiftool
              alsa-lib
              ffmpeg
              glfw
              libjpeg
              libmad
              libvorbis
              llvmPackages.openmp
              vulkan-headers
              vulkan-loader
              vulkan-tools
              zlib
            ];

            dontUseCmakeConfigure = true;

            makeFlags = [
              "DESTDIR=$(out)"
              "prefix="
              "VKDT_USE_RAWINPUT=2" # typically sets this by checking for `rustc --version`, lets save a dependency :)
              "VKDT_USE_MCRAW=false" # TODO: support mcraw
            ];

            meta = {
              mainProgram = "vkdt";
            };
          };

          default = vkdt-git;
        };

        devShells.default = pkgs.mkShell {
          inputsFrom = [ self.packages.${system}.vkdt-git ];
          buildInputs = with pkgs; [ gdb ];
          VK_LAYER_PATH = "${pkgs.vulkan-validation-layers}/share/vulkan/explicit_layer.d";
        };
      }
    );
}