[STM32WLx] Add examples

Co-Authored-By: jgromes <jan.gromes@gmail.com>

Author: matthijskooijman

examples/STM32WLx/STM32WLx_Channel_Activity_Detection/STM32WLx_Channel_Activity_Detection.ino

@@ -0,0 +1,61 @@
+/*
+   RadioLib STM32WLx Channel Activity Detection Example
+
+   This example uses STM32WLx to scan the current LoRa
+   channel and detect ongoing LoRa transmissions.
+   Unlike SX127x CAD, SX126x/STM32WLx can detect any part
+   of LoRa transmission, not just the preamble.
+
+   For default module settings, see the wiki page
+   https://github.com/jgromes/RadioLib/wiki/Default-configuration#sx126x---lora-modem
+
+   For full API reference, see the GitHub Pages
+   https://jgromes.github.io/RadioLib/
+*/
+
+// include the library
+#include <RadioLib.h>
+
+// no need to configure pins, signals are routed to the radio internally
+STM32WLx radio = new STM32WLx_Module();
+
+
+void setup() {
+  Serial.begin(9600);
+
+  // initialize STM32WLx with default settings
+  Serial.print(F("[STM32WLx] Initializing ... "));
+  int state = radio.begin(868.0);
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true);
+  }
+}
+
+void loop() {
+  Serial.print(F("[STM32WLx] Scanning channel for LoRa transmission ... "));
+
+  // start scanning current channel
+  int state = radio.scanChannel();
+
+  if (state == RADIOLIB_LORA_DETECTED) {
+    // LoRa preamble was detected
+    Serial.println(F("detected!"));
+
+  } else if (state == RADIOLIB_CHANNEL_FREE) {
+    // no preamble was detected, channel is free
+    Serial.println(F("channel is free!"));
+
+  } else {
+    // some other error occurred
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+
+  }
+
+  // wait 100 ms before new scan
+  delay(100);
+}

examples/STM32WLx/STM32WLx_Channel_Activity_Detection_Interrupt/STM32WLx_Channel_Activity_Detection_Interrupt.ino

@@ -0,0 +1,98 @@
+/*
+   RadioLib STM32WLx Channel Activity Detection Example
+
+   This example uses STM32WLx to scan the current LoRa
+   channel and detect ongoing LoRa transmissions.
+   Unlike SX127x CAD, SX126x/STM32WLx can detect any part
+   of LoRa transmission, not just the preamble.
+
+   For default module settings, see the wiki page
+   https://github.com/jgromes/RadioLib/wiki/Default-configuration#sx126x---lora-modem
+
+   For full API reference, see the GitHub Pages
+   https://jgromes.github.io/RadioLib/
+*/
+
+// include the library
+#include <RadioLib.h>
+
+// no need to configure pins, signals are routed to the radio internally
+STM32WLx radio = new STM32WLx_Module();
+
+
+void setup() {
+  Serial.begin(9600);
+
+  // initialize STM32WLx with default settings
+  Serial.print(F("[STM32WLx] Initializing ... "));
+  int state = radio.begin(868.0);
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true);
+  }
+
+  // set the function that will be called
+  // when LoRa packet or timeout is detected
+  radio.setDio1Action(setFlag);
+
+  // start scanning the channel
+  Serial.print(F("[STM32WLx] Starting scan for LoRa preamble ... "));
+  state = radio.startChannelScan();
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+  }
+}
+
+// flag to indicate that a packet was detected or CAD timed out
+volatile bool scanFlag = false;
+
+// this function is called when a complete packet
+// is received by the module
+// IMPORTANT: this function MUST be 'void' type
+//            and MUST NOT have any arguments!
+void setFlag(void) {
+  // something happened, set the flag
+  scanFlag = true;
+}
+
+void loop() {
+  // check if the flag is set
+  if(scanFlag) {
+    // reset flag
+    scanFlag = false;
+
+    // check CAD result
+    int state = radio.getChannelScanResult();
+
+    if (state == RADIOLIB_LORA_DETECTED) {
+      // LoRa packet was detected
+      Serial.println(F("[STM32WLx] Packet detected!"));
+
+    } else if (state == RADIOLIB_CHANNEL_FREE) {
+      // channel is free
+      Serial.println(F("[STM32WLx] Channel is free!"));
+
+    } else {
+      // some other error occurred
+      Serial.print(F("[STM32WLx] Failed, code "));
+      Serial.println(state);
+
+    }
+
+    // start scanning the channel again
+    Serial.print(F("[STM32WLx] Starting scan for LoRa preamble ... "));
+    state = radio.startChannelScan();
+    if (state == RADIOLIB_ERR_NONE) {
+      Serial.println(F("success!"));
+    } else {
+      Serial.print(F("failed, code "));
+      Serial.println(state);
+    }
+  }
+}

examples/STM32WLx/STM32WLx_Receive/STM32WLx_Receive.ino

@@ -0,0 +1,124 @@
+/*
+   RadioLib STM32WLx Receive Example
+
+   This example listens for LoRa transmissions using STM32WL MCU with
+   integrated (SX126x) LoRa radio.
+
+   To successfully receive data, the following settings have to be the same
+   on both transmitter and receiver:
+    - carrier frequency
+    - bandwidth
+    - spreading factor
+    - coding rate
+    - sync word
+    - preamble length
+   
+   This example assumes Nucleo WL55JC1 is used. For other Nucleo boards
+   or standalone STM32WL, some configuration such as TCXO voltage and
+   RF switch control may have to be adjusted.
+
+   For default module settings, see the wiki page
+   https://github.com/jgromes/RadioLib/wiki/Default-configuration#sx126x---lora-modem
+
+   For full API reference, see the GitHub Pages
+   https://jgromes.github.io/RadioLib/
+*/
+
+// include the library
+#include <RadioLib.h>
+
+// no need to configure pins, signals are routed to the radio internally
+STM32WLx radio = new STM32WLx_Module();
+
+// set RF switch configuration for Nucleo WL55JC1
+// NOTE: other boards may be different!
+static const RADIOLIB_PIN_TYPE rfswitch_pins[] =
+                         {PC3,  PC4,  PC5};
+static const Module::RfSwitchMode_t rfswitch_table[] = {
+  {STM32WLx::MODE_IDLE,  {LOW,  LOW,  LOW}},
+  {STM32WLx::MODE_RX,    {HIGH, HIGH, LOW}},
+  {STM32WLx::MODE_TX_LP, {HIGH, HIGH, HIGH}},
+  {STM32WLx::MODE_TX_HP, {HIGH, LOW,  HIGH}},
+  STM32WLx::END_OF_MODE_TABLE,
+};
+
+void setup() {
+  Serial.begin(9600);
+
+  // set RF switch control configuration
+  // this has to be done prior to calling begin()
+  radio.setRfSwitchTable(rfswitch_pins, rfswitch_table);
+
+  // initialize STM32WL with default settings, except frequency
+  Serial.print(F("[STM32WL] Initializing ... "));
+  int state = radio.begin(868.0);
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true);
+  }
+
+  // set appropriate TCXO voltage for Nucleo WL55JC1
+  state = radio.setTCXO(1.7);
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true);
+  }
+}
+
+void loop() {
+  Serial.print(F("[STM32WL] Waiting for incoming transmission ... "));
+
+  // you can receive data as an Arduino String
+  // NOTE: receive() is a blocking method!
+  //       See example ReceiveInterrupt for details
+  //       on non-blocking reception method.
+  String str;
+  int state = radio.receive(str);
+
+  // you can also receive data as byte array
+  /*
+    byte byteArr[8];
+    int state = radio.receive(byteArr, 8);
+  */
+
+  if (state == RADIOLIB_ERR_NONE) {
+    // packet was successfully received
+    Serial.println(F("success!"));
+
+    // print the data of the packet
+    Serial.print(F("[STM32WL] Data:\t\t"));
+    Serial.println(str);
+
+    // print the RSSI (Received Signal Strength Indicator)
+    // of the last received packet
+    Serial.print(F("[STM32WL] RSSI:\t\t"));
+    Serial.print(radio.getRSSI());
+    Serial.println(F(" dBm"));
+
+    // print the SNR (Signal-to-Noise Ratio)
+    // of the last received packet
+    Serial.print(F("[STM32WL] SNR:\t\t"));
+    Serial.print(radio.getSNR());
+    Serial.println(F(" dB"));
+
+  } else if (state == RADIOLIB_ERR_RX_TIMEOUT) {
+    // timeout occurred while waiting for a packet
+    Serial.println(F("timeout!"));
+
+  } else if (state == RADIOLIB_ERR_CRC_MISMATCH) {
+    // packet was received, but is malformed
+    Serial.println(F("CRC error!"));
+
+  } else {
+    // some other error occurred
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+
+  }
+}