build.gradle

plugins {
  id 'net.saliman.properties' version '1.6.0'
  id "java-library"
  id "org.sonarqube" version "6.3.1.5724"
}

sonar {
  properties {
    property "sonar.projectKey", "marklogic-spark"
    property "sonar.host.url", "http://localhost:9000"
    property "sonar.coverage.jacoco.xmlReportPaths", "marklogic-spark-connector/build/reports/jacoco/test/jacocoTestReport.xml"
  }
}

subprojects {
  apply plugin: "net.saliman.properties"
  apply plugin: "java-library"
  apply plugin: "jacoco"

  group = "com.marklogic"

  java {
    toolchain {
      languageVersion = JavaLanguageVersion.of(17)
    }
    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
  }

  // Allows for quickly identifying compiler warnings.
  tasks.withType(JavaCompile) {
    options.compilerArgs << '-Xlint:unchecked'
    options.deprecation = true
  }

  repositories {
    mavenCentral()

    // Commenting out temporarily while preparing for a release.
//    mavenLocal()
    maven {
      url = "https://bed-artifactory.bedford.progress.com:443/artifactory/ml-maven-snapshots/"
    }
  }

  test {
    useJUnitPlatform()
    finalizedBy jacocoTestReport
    testLogging {
      events = ['started', 'passed', 'skipped', 'failed']
      exceptionFormat = 'full'
    }
    environment "SEMAPHORE_API_KEY", semaphoreApiKey
    environment "SEMAPHORE_HOST", semaphoreHost
    environment "SEMAPHORE_PATH", semaphorePath
  }

  // See https://docs.gradle.org/current/userguide/jacoco_plugin.html .
  jacocoTestReport {
    dependsOn test
    reports {
      xml.required = true
    }
  }

  // Turning off coverage verification, as we haven't figured out how to configure Sonar correctly to pick up the jacoco
  // report from the "code-coverage-report" subproject and accurately capture coverage.
  // See https://docs.gradle.org/current/userguide/jacoco_plugin.html#sec:jacoco_report_violation_rules
  jacocoTestCoverageVerification {
    violationRules {
      rule {
        limit {
          minimum = 0.0
        }
      }
    }
  }
}