consult-line: start from top with initial selected candidate near the cursor

[Azkae]

I wanted to share some hack that I made to change the behavior of consult-line. (Initially shared here)

What I wanted is using consult-line-start-from-top with the selected candidate being near the cursor after filtering.

I like this behavior for a few reasons:

• I can see candidates around my cursor at a glance.
• I can easily jump to the first or last candidate of the file using M-< or M->
• I believe that was the default behavior of helm so I got used to it.

I'm sharing this since it may prove useful for other people, but also to see if there is a way to make it less hackish or maybe even properly supported.

(defvar consult--previous-point nil
  "Location of point before entering minibuffer.
    Used to preselect nearest headings and imenu items.")

(defvar consult--vertico-updated-selection nil
  "Used to see if vertico recomputed candidates.")

(defun consult--set-previous-point (&optional arg1 arg2)
  "Save location of point. Used before entering the minibuffer."
  (setq consult--previous-point (point)))

(defun vertico--set-updated-selection(&rest _)
  "Used to re-trigger a candidate selection after a new input"
  (setq consult--vertico-updated-selection t))

(defun my/closest-candidates-index (target candidates predicate)
  "Return the index of the closest candidate to TARGET using PREDICATE to extract candidate position."
  (cl-loop for candidate in candidates
           for index from 0
           for candidate-pos = (funcall predicate candidate)
           do (when (> candidate-pos target)
                (cl-return (max 0 (- index 1))))
           finally return (- index 1)))

(defun vertico--update-selected-candidate-maybe (orig-fun &rest args)
  "Pick the nearest candidate rather than the first if candidates were recomputed."
  (setq consult--vertico-updated-selection nil)
  (let ((result (apply orig-fun args)))

    (when (and consult--vertico-updated-selection
               consult--previous-point vertico--candidates
               (memq current-minibuffer-command
                     '(consult-org-heading consult-outline consult-line)))
      (setq vertico--index
            (max 0
                 (or (my/closest-candidates-index
                      consult--previous-point
                      vertico--candidates
                      (lambda (cand)
                        (cl-case current-minibuffer-command
                          (consult-outline
                           (car (consult--get-location cand)))
                          (consult-org-heading
                           (get-text-property 0 'consult--candidate cand))
                          (consult-line
                           (car (consult--get-location cand)))
                          (t (error "Unsupported command in vertico--update-selected-candidate-maybe")))))
                     (length vertico--candidates)))))

    result))

(advice-add #'consult-org-heading :before #'consult--set-previous-point)
(advice-add #'consult-outline :before #'consult--set-previous-point)
(advice-add #'consult-line :before #'consult--set-previous-point)
(advice-add #'vertico--update :around #'vertico--update-selected-candidate-maybe)
(advice-add #'vertico--recompute :after #'vertico--set-updated-selection)

(setq consult-line-start-from-top t)

Thank you for your work on consult !

[minad]

Thank you! I've seen your code snippet over at reddit. This issue has been discussed a few times. The problem is the inter-package coupling here, which I would like to avoid. I would like to find a more generic solution, for example keeping the wrap-around of the candidate list in consult-line (and additionally consult-outline) and displaying the candidates from the bottom at the top in Vertico if vertico-cycle is set to some special symbol wrap. Alternatively remove the entire wrapping around feature, and handle it completely via a special candidate selection function as you have it. In any case, all this needs experimentation to come up with a simple enough and clean solution, and I didn't find the time yet to do this.