spotty/build.gradle at master · spotty-java/spotty · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
plugins {
    id 'java'
    id 'groovy'
    id 'idea'
    id 'jacoco'
    id 'org.unbroken-dome.test-sets' version '4.0.0'
}

subprojects {
    apply plugin: 'java'
    apply plugin: 'groovy'
    apply plugin: 'idea'
    apply plugin: 'jacoco'
    apply plugin: 'org.unbroken-dome.test-sets'

    java.toolchain.languageVersion = JavaLanguageVersion.of(8)

    compileJava.options.encoding = 'UTF-8'

    repositories {
        mavenCentral()
    }

    testSets {
        testIntegration
    }

    dependencies {
        implementation "com.google.guava:guava:$googleGuavaVersion"

        compileOnly "org.slf4j:slf4j-api:$slf4jApiVersion"
        runtimeOnly "ch.qos.logback:logback-classic:$logbackClassicVersion"

        testImplementation "org.apache.groovy:groovy-all:$groovyVersion"
        testImplementation "org.spockframework:spock-core:$spockVersion"
        testImplementation "org.objenesis:objenesis:$objenesis"

        testIntegrationImplementation "org.apache.groovy:groovy-all:$groovyVersion"
        testIntegrationImplementation "org.spockframework:spock-core:$spockVersion"
        testIntegrationImplementation "org.objenesis:objenesis:$objenesis"
    }

    test {
        useJUnitPlatform()
    }

    testIntegration {
        useJUnitPlatform()
    }

    jacocoTestReport {
        dependsOn(test, testIntegration)
        executionData(test, testIntegration)

        afterEvaluate {
            classDirectories.setFrom(files(classDirectories.files.collect {
                fileTree(dir: it, exclude: [
                    "spotty/Spotty*",
                    "spotty/common/exception/*"
                ])
            }))
        }
    }

    jacocoTestCoverageVerification {
        dependsOn jacocoTestReport
        executionData(test, testIntegration)

        violationRules {
            rule {
                limit {
                    minimum = 0.8
                }

                excludes = [
                    'spotty.Spotty',
                    'spotty.common.exception.*'
                ]
            }
        }
    }

    check.dependsOn jacocoTestCoverageVerification
}