Build and bundle gemstone locally instead of prebuilt package

gemcore/build.gradle.kts

@@ -53,8 +53,7 @@ android {
 }
 
 dependencies {
-    //noinspection UseTomlInstead
-    api(libs.gemstone)
+    api(project(":gemstone"))
 
     api(libs.kotlinx.serialization.json)
     implementation(libs.compose.runtime.android)

gemstone/build.gradle.kts

@@ -0,0 +1,98 @@
+import org.jetbrains.kotlin.gradle.dsl.JvmTarget
+
+plugins {
+    id("com.android.library")
+    id("org.jetbrains.kotlin.android")
+}
+
+val gemstoneRoot = rootProject.projectDir.resolve("core/gemstone")
+val gemstoneSrc = gemstoneRoot.resolve("android/gemstone/src")
+val rustSrcDir = gemstoneRoot.resolve("src")
+val cratesDir = rootProject.projectDir.resolve("core/crates")
+val jniLibsDir = gemstoneSrc.resolve("main/jniLibs")
+val generatedKotlinDir = gemstoneSrc.resolve("main/java")
+
+android {
+    namespace = "com.gemwallet.gemstone"
+    compileSdk = 36
+
+    defaultConfig {
+        minSdk = 28
+        consumerProguardFiles(gemstoneRoot.resolve("android/gemstone/consumer-rules.pro"))
+    }
+
+    buildTypes {
+        release {
+            isMinifyEnabled = false
+            proguardFiles(
+                getDefaultProguardFile("proguard-android-optimize.txt"),
+                "proguard-rules.pro"
+            )
+        }
+    }
+
+    compileOptions {
+        sourceCompatibility = JavaVersion.VERSION_1_8
+        targetCompatibility = JavaVersion.VERSION_1_8
+    }
+
+    sourceSets {
+        getByName("main") {
+            java.srcDirs(generatedKotlinDir)
+            jniLibs.srcDirs(jniLibsDir)
+            manifest.srcFile(gemstoneSrc.resolve("main/AndroidManifest.xml"))
+        }
+        getByName("androidTest") {
+            java.srcDirs(gemstoneSrc.resolve("androidTest/java"))
+        }
+    }
+}
+
+kotlin {
+    compilerOptions {
+        jvmTarget.set(JvmTarget.JVM_1_8)
+    }
+}
+
+val bindgenKotlin = tasks.register<Exec>("bindgenKotlin") {
+    description = "Generate Kotlin bindings from gemstone via uniffi"
+    workingDir = gemstoneRoot
+    inputs.dir(rustSrcDir)
+    inputs.dir(cratesDir)
+    inputs.file(gemstoneRoot.resolve("Cargo.toml"))
+    outputs.dir(generatedKotlinDir.resolve("uniffi"))
+    commandLine("just", "bindgen-kotlin")
+}
+
+val buildCargoNdk = tasks.register<Exec>("buildCargoNdk") {
+    description = "Build gemstone native libraries using cargo-ndk"
+    workingDir = gemstoneRoot
+    inputs.dir(rustSrcDir)
+    inputs.dir(cratesDir)
+    inputs.file(gemstoneRoot.resolve("Cargo.toml"))
+    outputs.dir(jniLibsDir)
+    commandLine(
+        "cargo", "ndk",
+        "-t", "arm64-v8a",
+        "-t", "armeabi-v7a",
+        "-t", "x86_64",
+        "-o", jniLibsDir.absolutePath,
+        "build", "--lib"
+    )
+}
+
+afterEvaluate {
+    tasks.matching { it.name.matches(Regex("compile(Debug|Release)Kotlin")) }.configureEach {
+        dependsOn(bindgenKotlin)
+    }
+    tasks.matching { it.name.matches(Regex("merge(Debug|Release)JniLibFolders")) }.configureEach {
+        dependsOn(buildCargoNdk)
+    }
+}
+
+dependencies {
+    api("net.java.dev.jna:jna:5.18.1@aar")
+    implementation("androidx.core:core-ktx:1.17.0")
+    androidTestImplementation("androidx.test.ext:junit:1.3.0")
+    androidTestImplementation("androidx.test.espresso:espresso-core:3.7.0")
+}

gradle/libs.versions.toml

@@ -51,7 +51,6 @@ mockkVersion = "1.14.9"
 espressoCore = "3.7.0"
 
 wallet-core = "4.3.22"
-gemstone = "1.0.11"
 
 glance-widgets = "1.1.1"
 
@@ -120,9 +119,6 @@ walletconnect-web3wallet = { module = "com.reown:walletkit" }
 # Wallet - core
 wallet-core = { module = "com.trustwallet:wallet-core", version.ref = "wallet-core" }
 
-# Gem Stone
-gemstone = { module = "com.gemwallet.gemstone:gemstone", version.ref = "gemstone" }
-
 # qr code scanning
 zxing-core = { module = "com.google.zxing:core", version.ref = "zxing-core" }
 camera-view = { module = "androidx.camera:camera-view", version.ref = "camera2" }

settings.gradle.kts

@@ -6,6 +6,7 @@ pluginManagement {
     }
 }
 rootProject.name = "wallet"
+include(":gemstone")
 include (":app")
 include(":blockchain")
 include(":gemcore")