Helm v.s. Consult: can consult-buffer-sources replicate helm-for-files?

[BenedictHW]

Good evening. There's just one thing stopping me from switching from Helm to the consult stack, I'm trying to have Consult Buffer run a search on the contents of a particular project. As of now, the code does not give me any errors, even with toggle on debug enabled. However, no results from bhw/consult-source-project-maria shows up. Does anyone have any examples of using :async as part of their consult sources? I would appreciate any help or examples.

 (defvar bhw/consult-source-project-maria
    `(:name     "Project-Maria rg"
      :narrow   (?m . "Maria")
      :category consult-grep
      :history  (:input consult--grep-history)
      :state    ,#'consult--grep-state
      :action   ,#'consult--file-action
      :async    ,(lambda (sink)
                   (consult--async-process
                    sink
                    (consult--ripgrep-make-builder (list (expand-file-name "~/project-maria")))))))

(add-to-list 'consult-buffer-sources 'bhw/consult-source-project-maria 'append)

The helm configuration that works.

  (defvar bhw/helm-source-maria-ag
    (helm-make-source "Project Maria - AG" 'helm-do-ag-class
      :candidates-process
      (lambda ()
        (helm-ag--do-ag-candidate-process +project-maria-dir+)))
    "To search Project Maria files from `helm-for-files'.
`helm-ag--do-ag-set-source' used as exemplar.")

  (defvar bhw/helm-source-emacs-commands
    (helm-build-sync-source "Emacs Commands"
      :candidates (lambda ()
                    (let ((cmds))
                      (mapatoms (lambda (elt)
                                  (when (commandp elt)
                                    (push (symbol-name elt) cmds))))
                      cmds))
      :coerce #'intern-soft
      :action #'command-execute)
    "A simple helm source for Emacs commands. Used in `helm-for-files'.")

(setf   helm-for-files-preferred-list
        '(helm-source-recentf
          bhw/helm-source-fd
          bhw/helm-source-maria-ag
          bhw/helm-source-emacs-commands))

Thank you for your time.

[minad]

It should be possible to replicate helm-for-files. However asynchronous sources are not yet used widely. I use them in my configuration and maybe some other packages use them too. You can either use consult--dynamic-collection or consult--process-collection:

(defvar dynamic-source
  (list :async (consult--dynamic-collection (lambda (input) (list of dynamically produced candidates)))))

(defvar process-source
  (list :async (consult--process-collection #'consult--man-builder)))

See also ada079d.

[BenedictHW]

Thank you Minad! The following code works :)

  (defvar bhw/consult-source-project-maria
    `(:name     "Project-Maria rg"
      :narrow   (?m . "Maria")
      :category consult-grep
      :history  (:input consult--grep-history)
      :state    ,#'consult--grep-state
      :action   ,#'consult--file-action
      :async
      ,(consult--process-collection
           (consult--ripgrep-make-builder
            (list (expand-file-name "~/project-maria")))
         :transform
         (consult--grep-format
          (consult--ripgrep-make-builder
           (list (expand-file-name "~/project-maria"))))
         :file-handler t)))

Gemini pro kept hallucinating -- but it did give me good information, told me to look at consult--grep-format -- so I just manned up and read the source code. I will generalize this and post it on the Wiki (as all current examples use :items and none use :async) if you don't mind.

[BenedictHW]

https://github.com/minad/consult/wiki#asynchronus-consult-buffer-source-example

Thanks for your continued work on emacs Minad. Awesome work.