Context specific Interlisp symbols?

[RyanBurnside]

Hello,

Currently I'm implementing a LOGO turtle graphics like DSL and I've hit a bit of a rut with symbol names. I'm used to Common Lisp where functions and symbols live in different areas. Symbols being 'foo and function references being #'foo.

I have two choices and both seem "stuck" in naming collisions.

1. I can either create new functions RIGHT and LEFT (but RIGHT appears to be associated with a Record type already if I go ED(RIGHT) .

2. I can go RT and LT which are also very traditional. However as expected LT is then reserved when I attempt to go ED(LT) to create a new function.

This may simply come down to "pick better names" but that's a last resort as I'd like my implementation to feel as close to tradition as possible. I could resort to Common Lisp methods but I've already rewritten my library in (mostly) Interlisp.

Currently I've settled for RT and LTT but LTT pains me to keep due to asymmetry.
I'll attach my file for hacking. :)

Here are the collisions.
I've mostly been using ED(MY-DEF) so if there are other options do tell.

Sincerely,
Ryan Burnside

Code for hacking:

(DEFINE-FILE-INFO �PACKAGE "INTERLISP" �READTABLE "INTERLISP" �BASE 10)

��(FILECREATED "22-Apr-2026 00:19:45" ��{DSK}<home>ryan>il>TURT.LISP;15�� 4365   

      :CHANGES-TO (FNS FD)

      :PREVIOUS-DATE "20-Apr-2026 22:14:24" {DSK}<home>ryan>il>TURT.LISP;14)


(PRETTYCOMPRINT TURTCOMS)

(RPAQQ ��TURTCOMS�� ((RECORDS TURTLE)
                 (FNS BK CREATE-TURTLE DRWFN FACE FD JMP LTT PD PENDSH PENW PU RT TURT-TEST TURTNGON
                      TURTSTAR)))
(DECLARE%: EVAL@COMPILE

(RECORD ��TURTLE�� (X Y DIRECTION PENDOWN PENSIZE PENDASH DRAWFN RADIANSFLAG))
)
(DEFINEQ

(��BK��
  [LAMBDA (TURT AMOUNT)
    (��FD�� TURT (MINUS AMOUNT])

(��CREATE-TURTLE��
  [LAMBDA (X Y DIRECTION DRAWFN PENSIZE PENDASH PENDOWN RADIANSFLAG)
    (��create�� TURTLE
           X _ (OR X 0)
           Y _ (OR Y 0)
           DIRECTION _ (OR DIRECTION 90)
           DRAWFN _ [OR DRAWFN '(LAMBDA (X Y X2 Y2 PENSIZE PENDASH)
                                  NIL]
           PENSIZE _ (OR PENSIZE 1)
           PENDASH _ (OR PENDASH NIL)
           PENDOWN _ (OR PENDOWN T)
           RADIANSFLAG _ (OR RADIANSFLAG NIL])

(��DRWFN��
  [LAMBDA (TURT FN)
    (��replace�� DRAWFN ��of�� TURT ��with�� FN)
    TURT])

(��FACE��
  [LAMBDA (TURT ANGLE)
    (��replace�� DIRECTION ��of�� TURT ��with�� ANGLE])

(��FD��
  [LAMBDA (TURT AMOUNT)
    (��with�� TURTLE TURT (LET* [(NEWX (PLUS X (TIMES (COS DIRECTION RADIANSFLAG)
                                                  AMOUNT)))
                             (NEWY (PLUS Y (TIMES (SIN DIRECTION RADIANSFLAG)
                                                  AMOUNT]
                            (��if�� (AND PENDOWN DRAWFN)
                                ��then�� (APPLY* DRAWFN X Y NEWX NEWY PENSIZE PENDASH))
                            (SETQ X NEWX)
                            (SETQ Y NEWY)
                            TURT])

(��JMP��
  [LAMBDA (TURT X Y)
    (��replace�� X ��of�� TURT ��with�� X)
    (��replace�� Y ��of�� TURT ��with�� Y)
    TURT])

(��LTT��
  [LAMBDA (TURT ANGLE)
    (��RT�� TURT (MINUS ANGLE))
    TURT])

(��PD��
  [LAMBDA (TURT)
    (��REPLACE�� PENDOWN ��OF�� TURT ��WITH�� T)
    TURT])

(��PENDSH��
  [LAMBDA (TURT DASH-LIST)
    (��replace�� PENDASH ��of�� TURT ��with�� DASH-LIST)
    TURT])

(��PENW��
  [LAMBDA (TURT SIZE)
    (��replace�� PENSIZE ��of�� TURT ��with�� (��if�� (< SIZE 0)
                                      ��then�� 0
                                    ��else�� SIZE))
    TURT])

(��PU��
  [LAMBDA (TURT)
    (��replace�� PENDOWN ��of�� TURT ��with�� NIL)
    TURT])

(��RT��
  [LAMBDA (TURT ANGLE)
    [LET* ((MOD-VAL (��if�� (��fetch�� RADIANSFLAG ��of�� TURT)
                        ��then�� (TIMES CL:PI 2.0)
                      ��else�� 360.0))
           (CURRENT-ANGLE (��fetch�� DIRECTION ��of�� TURT)))
          (��with�� TURTLE TURT (SETQ DIRECTION (CL:MOD (- CURRENT-ANGLE ANGLE)
                                                   MOD-VAL]
    TURT])

(��TURT-TEST��
  [LAMBDA NIL
    (LET* ((W (CREATEW (CREATEREGION 200 200 400 400)
                     "TURT-TEST"))
           (TT (��CREATE-TURTLE��)))
          [��DRWFN�� TT `(LAMBDA (X Y X2 Y2 PENSIZE PENDASH)
                       (DRAWLINE X Y X2 Y2 PENSIZE NIL ,W NIL PENDASH]
          (��JMP�� TT 200 200)
          (FRPTQ 6 (��TURTSTAR�� TT 7 120 3)
                 (��RT�� TT 60))
          (CONS TT W])

(��TURTNGON��
  [LAMBDA (TURT NUMSIDES SIDELENGTH LEFTTURN)
    (LET [(TURNDEG (��if�� (��fetch�� RADIANSFLAG ��of�� TURT)
                       ��then�� (/ (TIMES CL:PI 2.0)
                               NUMSIDES)
                     ��else�� (/ 360.0 NUMSIDES]
         (FRPTQ NUMSIDES (��FD�� TURT SIDELENGTH)
                (��if�� LEFTTURN
                    ��then�� (��LTT�� TURT TURNDEG)
                  ��else�� (��RT�� TURT TURNDEG])

(��TURTSTAR��
  [LAMBDA (TURT NUMPOINTS SIDELENGTH SKIP LEFTTURN)
    (LET [(TURNDEG (��if�� (��fetch�� RADIANSFLAG ��of�� TURT)
                       ��then�� (/ (TIMES 2.0 CL:PI SKIP)
                               NUMPOINTS)
                     ��else�� (/ (TIMES 360.0 SKIP)
                             NUMPOINTS]
         (FRPTQ NUMPOINTS (��FD�� TURT SIDELENGTH)
                (��if�� LEFTTURN
                    ��then�� (��LTT�� TURT TURNDEG)
                  ��else�� (��RT�� TURT TURNDEG])
)
(DECLARE%: DONTCOPY
  (FILEMAP (NIL (569 4342 (BK 579 . 643) (CREATE-TURTLE 645 . 1108) (DRWFN 1110 . 1200) (FACE 1202 . 
1290) (FD 1292 . 1865) (JMP 1867 . 1993) (LTT 1995 . 2069) (PD 2071 . 2155) (PENDSH 2157 . 2263) (PENW
 2265 . 2473) (PU 2475 . 2561) (RT 2563 . 2960) (TURT-TEST 2962 . 3380) (TURTNGON 3382 . 3832) (
TURTSTAR 3834 . 4340)))))
STOP

[pamoroso]

Some Interlisp applications and systems use namespace-ish prefixes in symbol names such as NC. in Notecards for symbols like NC.CardP and NC.DeleteNoteCard.

However, something like TG.LT and TG.RT drifts from tradition. A workaround that improves symmetry is to have a single turn function, say, TURN, which accepts a direction symbol LEFT or RIGHT as an additional argument: (TURN 'RIGHT 90).

[nbriggs]

I don't have a general answer to context specific symbols, but in this case it would be OK to define LT as a function, as that won't interfere with its CLISP definition. When you do ED(LT) you're asking it to edit some definition, and since it has a property list ED goes ahead with that. You can do ED(LT FNS) and since it does not (yet) have a FNS definition it will ask if you want a LAMBDA or NLAMBDA dummy definition. Go ahead and give it the expected definition. Once it has both a FNS and a PROPERTY-LIST definition, if you don't ask to edit a particular one (e.g., you do ED(LT) rather than ED(LT FNS)) it will ask which definition to edit. Type enough to disambiguate the types presented.

[MattHeffron]

It seems that the prefixed-names are just using packages without using packages.

[RyanBurnside]

Thanks for the help!

I was able to simply use ED(LT FNS) to create a new definition.

All good now.

[nbriggs]

You could also have done (RENAME 'LTT 'LT 'FNS) and it would have asked if you wanted to change the entry in TURTCOMS as well as moving the function definition to LT and erasing the definition from LTT.

[RyanBurnside]

Ah nice, does that harness Masterscope under the hood?
Much better copy/pasting the code into a new function then doing DELDEF and looking through my files.

[nbriggs]

See the documentation for RENAME, CHANGECALLERS, EDITCALLERS -- if you've done an . ANALYZE ALL ON TURT you can tell it the method is 'MASTERSCOPE and in theory it should use the Masterscope database to drive the replacement. Otherwise it uses the DEFAULTRENAMEMETHOD (which I think is (EDITCALLERS CAREFUL) - I'm not sure what the requirements are for that to do the right thing. For all these, as usual, get the documentation with (fn ?<cr> at the exec.