add lift for Compose

[safareli]

What think about adding something like this:

liftC :: forall f g. Functor f => Applicative g => f ~> Compose f g
liftC = map pure >>> Compose

[garyb]

Is there a reason to prefer that to

liftC :: forall f g. Applicative f => Functor g => g ~> Compose f g
liftC = Compose <<< pure

? 😉

(I mean, for your use case I'm sure there is, just saying in general I'm not sure there's an obvious choice here). I suppose there's an opportunity for another Inject here too perhaps.

[safareli]

yes that would also be a valid function to exist. I think we should have both, what you think about names tho, lift, liftUp?

What you mean by Inject btw?

[garyb]

I mean you could have a class based function that chooses which of these functions to use based on the type, using an instance chain.

[safareli]

ah you mean something like this https://github.com/purescript/purescript-either/blob/v4.1.1/src/Data/Either/Inject.purs#L8-L10

that would be even better.

[safareli]

Here it is:

class Lift f g where
  lift :: f ~> g

instance liftReflexive :: Lift a a where
  lift = identity

else instance liftLeft :: (Functor f, Applicative g) => Lift f (Compose f g) where
  lift = Compose <<< map pure

else instance liftRight :: (Applicative g, Lift f h) => Lift f (Compose g h) where
  lift = Compose <<< pure <<< lift


lift1 :: Identity ~> Compose (Either Unit) (Compose Maybe (Compose (Const Unit) Identity))
lift1 = lift

lift2 :: Identity ~> Compose (Either Unit) (Compose Identity (Compose (Const Unit) Maybe))
lift2 = lift

lift3 :: Identity ~> Compose Identity (Compose (Either Unit) (Compose (Const Unit) Maybe))
lift3 = lift

-- This compiles too but I guess Inject of Either will have same issue, and it's ok?
lift4 :: Identity ~> Compose Identity (Compose Identity (Compose (Const Unit) Maybe))
lift4 = lift

-- this will fail with  ERROR: No type class instance was found for Lift Identity Maybe
lift4 :: Identity ~> Compose Maybe (Compose (Either Unit) (Compose (Const Unit) Maybe))
lift4 = lift

Where should we add this, to Data.Functor.Compose or Data.Functor.Compose.Inject or Data.Functor.Compose.Lift?

[safareli]

Ping

[JordanMartinez]

@garyb Should we get this in before v0.14.0? It's not breaking, but seems trivial to do.

I think we might want to rename the lift1 functions to liftC1 so one can use both liftC2 from here and lift2 from Apply in the same file.